symbol ShutterPin=0
symbol CameraPowerPin=1
symbol TrailFeederSwitchPin=pin2
symbol MotionSensorInputPin=pin3
symbol LEDpin=4
symbol ActivityMode=bit0 '0=off and 1 = on
symbol StartWithWalkTestONorOff=bit1
symbol CameraIsONorOFF=bit2 'keep track of camera being on or off for activity mode
symbol TimeToTurnCamOnToRefreshFlash=w3
symbol TmeWaitAfterCamOnToPresShuter=w4
symbol DelayBetweenPictures=w5
symbol TimeForWalkTestToEnd=w6 'delay for walktest
symbol i=b1
disablebod
Low ShutterPin
Low CameraPowerPin
Low LEDpin
input 2
CameraIsONorOFF = 0
Pause 1000
'THE NUMBERS BETWEEN THE 2 LINES OF PLUS SIGNS ARE ALL YOU NEED_
'TO CHANGE FOR CUSTOM TIMINGS ETC.			
'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++    
'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++   
   
TimeToTurnCamOnToRefreshFlash=25000	'Time to refresh camera. Multiply this number by 0.144 and_
						'that's how many seconds before the camera will be refreshed._
						'Exapmle (25,000 x 0.144 = 3600 seconds/60 = 1 hour)"
						'25,000 = 1 hour, 50,000 = 2 hours etc.
						
						
TmeWaitAfterCamOnToPresShuter=1200  '1200 = 1.2 Seconds, 2000 =  2 seconds etc.

StartWithWalkTestONorOff = 1        'on = 1 off = 0

DelayBetweenPictures=26             'multiply this number by 2.3 to set the delay(in seconds)_
						'between pictures in feeder mode._
						'Example 26 x 2.3 = 60 seconds    

TimeForWalkTestToEnd = 208          'Time for  walktest. Multiply this number by 0.144 and_
						'that's how many seconds beforer walktest will end._
						'Exapmle (208 x 0.144 = 30 seconds)
						
'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++    
'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++    
Walktst:
IF StartWithWalkTestONorOff = 1 Then
	w1=w1+1 
	NAP 3
	IF MotionSensorInputPin = 0 Then
		High LEDpin
		Pause 1000
		Low LEDpin
		Pause 3000 'for sensor to settle
		w1=0
	EndIF
	IF w1 >=TimeForWalkTestToEnd Then
		StartWithWalkTestONorOff = 0
		For i = 1 to 10
			High LEDpin
			Pause 200
			Low LEDpin
			Pause 100
		next i
		GoTo lowpower
	EndIF
EndIF
GoTo Walktst
lowpower:
IF MotionSensorInputPin=0 Then
	IF CameraIsONorOFF=0 Then
		Pause 10
		IF TrailFeederSwitchPin = 0 Then
			ActivityMode=0
		Else
			ActivityMode=1
		EndIF
	EndIF
	IF ActivityMode = 0 Then
		If CameraIsONorOFF=0 Then
			Pause 10	
			High CameraPowerPin	' Turn Camera ON
			Pause   300
			Low CameraPowerPin
			CameraIsONorOFF=1
			Pause   TmeWaitAfterCamOnToPresShuter
		endif
		High ShutterPin			' Take a Picture
		Pause 3000
		Low ShutterPin
		Sleep 5
		High CameraPowerPin		' Turn Camera OFF
		Pause   300
		Low CameraPowerPin
		CameraIsONorOFF=0
		w1=0
		Sleep DelayBetweenPictures
	EndIF
	IF ActivityMode = 1 Then
		IF CameraIsONorOFF=0 Then
			Pause 10	
			High CameraPowerPin	' Turn Camera ON
			Pause   300
			Low CameraPowerPin
			CameraIsONorOFF=1
			Pause   TmeWaitAfterCamOnToPresShuter
		EndIF
		High ShutterPin			' Take a Picture
		Pause 3000
		Low ShutterPin
		Pause   1000
	EndIF
	w2=0
EndIF
IF CameraIsONorOFF=1 Then
	w1=w1+1
	IF w1>=300 Then 'Keep Camera on for 30 seconds for Activity Mode
		High CameraPowerPin		' Turn Camera ON
		Pause   1000
		Low CameraPowerPin
		CameraIsONorOFF=0
		w1=0
		Sleep 2
	EndIF
EndIF


w2=w2+1
IF w2 >= TimeToTurnCamOnToRefreshFlash Then
	High CameraPowerPin				' Turn Camera ON
	Sleep 1
	Low CameraPowerPin
	Sleep 5
	High CameraPowerPin				' Turn Camera ON
	Sleep 1
	Low CameraPowerPin
	w2=0
	Pause 100
EndIF
NAP 3	
GoTo lowpower				' Do it forever
End